//----------------------------------------
// BEÁLLÍTÁSOK

beállítások(koordináták,ki)
égboltszín(#0,#0)

//----------------------------------------
// Textúrás háttérgömb
skydome(sky360/2k_stars.jpg)


//---------------------------------------
// Részecskék textúrája
particle(particle/particle02.png)


//---------------------------------------
// Spirál paraméterek
a=1
b=0.3


//---------------------------------------
//  Csoport definiálása 

csoport() DEF GALAXIS


  //-------------------------------------
  // Ciklus 0-360 fokig 90 fokos lépésekkel
  // Azaz 4 karja lesz a galaxisnak
  // Érdemes 60, esetleg 45, 30 fokos lépésekkel is tesztelni
  
  for(s,0,360,90)
      forgás(0,0,s)


      // pontfelhő tefiniálása 
      // #333355 sínű, 1.5 méretű pontokkal
      pontfelhő(#333355,1.5) def GALAXIS_A[s]
         
         //-------------------------------
         // 120 elemből áll egy kar
         for(t,0,120)

             tt=t/20


             //-----------------------------------------
             // spirál számítása + 0.1 véletlen
             
             x=a*exp(b*tt)*cos(tt)+rand(-1,1)/10
             y=a*exp(b*tt)*sin(tt)+rand(-1,1)/10
             z=rand(-1,1)/10  

             pont(x,y,0)
 
             r=sqrt(x*x+y*y)
             
             //------------------------
             // Minden pont körül lesz 4 db
             // további véletlen pont
             
             for(v,1,4)
                 xx=x+rand(-5,5)/10
                 yy=y+rand(-5,5)/10
                 zz=z+rand(-5,5)/(10*r)
                 pont(xx,yy,zz)
             next(v)

        next(t)
     pontfelhő.vége()

     csoport.add(GALAXIS_A[s])   
  
  next(s)
  
//--------------------------------
// Forgás animáció
animáció(AN1,10)
 kulcs(  0%, 0, 0,  0)
 kulcs( 50%, 0, 0,  -180)
 kulcs(100%, 0, 0,  -359)
animáció.forgás(GALAXIS,AN1)  
  

  
csoport.vége()   


camera(START, -0.11, -10.37, 4.09, -0.05, -0.34, -0.85)
camera(TOP, 0.01, -3.61, 14.56, 0.18, 0.28, -0.14)